flake.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91

{
  description = "Hyprland Live Wallpaper";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = nixpkgs.legacyPackages.${system};
      in
      {
        packages.default = pkgs.rustPlatform.buildRustPackage {
          pname = "hyprland-live-wallpaper";
          version = "0.1.0";
          src = ./.;
          cargoLock.lockFile = ./Cargo.lock;
          nativeBuildInputs = with pkgs; [ pkg-config ];
          buildInputs = with pkgs; [
            wayland
            libxkbcommon
            vulkan-loader
            wayland-protocols
          ];
        };

        devShells.default = pkgs.mkShell {
          buildInputs = with pkgs; [
            rustc
            clippy
            rustfmt
            cargo
            pkg-config
            wayland
            libxkbcommon
            vulkan-loader
            wayland-protocols
          ];
        };
      }
    )
    // {
      nixosModules.default =
        {
          config,
          lib,
          pkgs,
          ...
        }:
        with lib;
        let
          cfg = config.services.hyprland-live-wallpaper;
        in
        {
          options.services.hyprland-live-wallpaper = {
            enable = mkEnableOption "Hyprland Live Wallpaper service";
            shader = mkOption {
              type = types.str;
              default = "default.wgsl";
              description = "Shader file to use";
            };
          };

          config = mkIf cfg.enable {
            systemd.user.services.hyprland-live-wallpaper = {
              description = "Hyprland Live Wallpaper";
              wantedBy = [ "graphical-session.target" ];
              after = [ "graphical-session.target" ];
              serviceConfig = {
                Type = "simple";
                ExecStart = "${
                  self.packages.${pkgs.system}.default
                }/bin/hyprland-live-wallpaper --shader ${cfg.shader}";
                Restart = "on-failure";
                Environment = [
                  "RUST_LOG=info"
                ];
              };
            };
          };
        };
    };
}